:: Launch GTA Online Patch (v1.1)
::   This batch file will automatically launch GTAV if not started, look for the process and inject using Xenos
::   You should probably at minimum change the GTADIR parameter below to where your GTA5.exe is
::   It will run Xenos64 in the folder the bat file is ran from, for the profile "OnlinePatch.xpr64"

:: May not work on steam due to different launch system, but will automatically launch gtav (and the rockstar launcher!)

:: Links
::   Xenos 					- https://github.com/DarthTon/Xenos
::   Online Patch Booster 	- https://github.com/QuickNET-Tech/GTAO_Booster_PoC
@echo off

:: 	!!! These variables may need to be changed

:: 	The directory where PlayGTAV.exe and GTAV.exe are located
Set GTADir="S:\Grand Theft Auto V"
:: 	Is the game STEAM or WAREHOUSE? 1 for STEAM, 0 for WAREHOUSE 
Set IsSteamVersion=1
:: 	How long until after process detected to inject? (in seconds)
Set WaitToInject=1
::  The name of the injector profile with the extension 
Set ProfileName=OnlinePatch.xpr64
:: 	The directory to find the executable, defaults to location of this .bat file
set ExecutableDir="%cd%"


:: Executables
Set Process=GTA5.exe
Set RockstarLauncher=Launcher.exe
Set Executable=Xenos64.exe

:: If GTA5.exe not running, starts via PlayGTAV.exe (May not work on Steam version)
cd /D %GTADir%
tasklist /NH /FI "imagename eq %Process%" 2>nul |find /i "%Process%" >nul
If errorlevel 1 (
	echo Game is not running, starting. STEAM: %IsSteamVersion%
	If IsSteamVersion equ 1 (
		start "" "steam://run/271590//-goStraightToMP -StraightIntoFreemode/"
	) else start PlayGTAV.exe -goStraightToMP -StraightIntoFreemode 
)
 
:: Starts looking for the process
echo Looking for %Process%...
:findGTA
tasklist /NH /FI "imagename eq %Process%" 2>nul |find /i "%Process%" >nul
If not errorlevel 1 (
	:: If process is found, inject.
	echo GTAV Found, Running %Executable% for Profile %ProfileName%
	cd /D %ExecutableDir%
	timeout /t %WaitToInject%
    echo Running executable
	start /WAIT %Executable% --run %ProfileName%
	echo Executable ran, will automatically close when game exits.
	goto waitForGameExit
) else (
	:: Process still not found, continue loop after 1s
	timeout /t 1 /nobreak > nul
	goto findGTA
	
)

:waitForGameExit
tasklist /NH /FI "imagename eq %Process%" 2>nul |find /i "%Process%" >nul
If errorlevel 1 (
	echo Detected game has closed, exiting...
	timeout /T 5 /nobreak > nul
	echo Closing social club launcher
	wmic process where name="%RockstarLauncher%" call terminate
) else (
	timeout /t 6 /nobreak > nul
	goto waitForGameExit
)